Auto-Install for Dungeon Crawl

I like to live on the edge and play the latest and greatest and buggiest version of Dungeon Crawl, the beta, which can be obtained here. Updates happen as quickly as once a week. That represents a minor chore for the player. Not much, I know--just deleting the old files, unpacking the new, and moving those files into the right directory. In my opinion, if there's any time to be wasted, it should be wasted playing Dungeon Crawl. With that in mind, I took time out of my busy day to construct yet another handy-dandy batch file to fully automate the installation process. This utility installs Dungeon Crawl Stone Soup in less than five seconds and removes all temporary files as well as the Crawl archive itself.

Like all batch files found here, this one requires modification to reflect the proper pathnames on your PC. This batch file assumes that you are downloading the beta to a directory called "c:\pelf". If that isn't true, then correct the batch. It also assumes that your game is installed at \games\crawl, which seems logical. It does all the work - deleting the old game, installing the new one, and then cleaning up afterwards. A batch file should clean up after itself, by Cracky! So says Igor.

Requirements: WinRAR. I know, I know. Costs money. I tried using Unrar, the command line version of WinRAR, but it will not work with ZIP archives for some unknown reason. You could replace WinRAR with some kind of unzipping utility, but I am not familiar with ZIP utilities. You're on your own if you go that route.

This WORKS under Windows XP. If Microsoft suckered you into going with Vista, you're on your own. I believe a few minor mods to the pathnames would get this working with later versions of Windows. Why Microsoft wants to change pathnames all the time, I don't know, but there is little about Microsoft that can be understood without a spycam in their marketing department.

Update 3/25/2010

I added a few lines to append my preferences to tiles_options.txt so that I don't have to keep modifying the file every time I install a new version of Crawl. The same technique could be used to make mods to any of the other settings. Just remember that >> signifies "append."

Update 5/26/2010

Designated variables for the directories. A few mods added as well.

Update 7/25/2010

There is now an Installation version available for download as well as the Windows Tiles version. This batch eliminates the need for the Installation version. It is faster than the Installer.

Update 6/04/2011

Updated to handle either the dev Tiles or stable Tiles. I still use this, because it is ten times faster and does not use Windows's complicated pathnames, but instead the simple pathname of c:\games\crawl, which my regen.bat uses by default.

Update 8/23/2012

Updated zip filename to work with .11.

Update 10/05/2012

Ditto.

---

@echo off
cls
echo Install-New-Crawl.bat for Dungeon Crawl
echo by igor
echo http://techlorebyigor.blogspot.com
echo.Updated 10-05-2012
echo.
echo This utility will install the newest version of crawl, whatever it may be.
echo.You must have WinRar installed in its default directory for this to work.
echo.
echo.*** Note: The old version will be deleted, including any saved games! ***
rem ---------------------------------------
rem change variables as needed here. 
rem ---------------------------------------
set dldir=c:\pelf
set unzipper="\Program Files\WinRAR\winrar.exe"
set gamedir=c:\games
set crawldir=crawl
rem ---------------------------------------
echo.Review the following variables:
echo.
echo.Your download directory = %dldir%
echo.Your unzipper = %unzipper%
echo.Crawl will be installed to %gamedir%\%crawldir%
if not exist %unzipper% goto WinRarErr
set dlfile=crawl_
rem the boys keep changing the zip name
if not exist "%dldir%\%dlfile%*" set dlfile=stone_soup
if not exist "%dldir%\%dlfile%*" goto NoPelf

if not exist %gamedir% md %gamedir%
cd %gamedir%

if exist %crawldir% rd %crawldir% /S /Q
md %crawldir%
if exist temp rd temp /S /Q
md temp
cd temp
rem dev team stashes crawl within a directory with similar name as zip,
rem so let's fix that now
move "%dldir%\%dlfile%*.*" igor.zip

%unzipper% x "%gamedir%\temp\igor.zip"

rem this is the directory created by the archive
cd %dlfile%*
xcopy *.* "%gamedir%\%crawldir%" /S /D
cd %gamedir%
rd temp /S /Q

rem ---------------------------------------
rem Review this section and replace with
rem your own mods.
rem 
rem igor's chosen mods to tiles_options.txt
rem ---------------------------------------
rem cd "%gamedir%\%crawldir%\settings"
rem echo tile_update_rate = 2500   >> tiles_options.txt
rem echo tile_runrest_rate = 300   >> tiles_options.txt
rem ---------------------------------------
rem igor's chosen mods 
rem ---------------------------------------
rem echo name = glorious igor >> init.txt
rem echo remember_name = true >> init.txt
rem echo restart_after_game = false >> init.txt
rem echo M:1 >> macro.txt
rem echo A:Zap >> macro.txt
rem ---------------------------------------
rem add your own mods here
rem ---------------------------------------
exit 

:WinRarErr
echo. ERROR: WinRar is a required program to unpack the archive.
set dlfile=crawl*
if not exist "%dldir%\%dlfile%*" set dlfile=stone_soup*
if not exist "%dldir%\%dlfile%*" goto NoPelf
pause
exit

:NoPelf
echo. ERROR: Cannot find the crawl archive (expected in %dldir%)
pause
exit