Dungeon Crawl Script, Two Years Later

I haven't touched the Dungeon Crawl script in two years, until now. It still works like a charm. I am quite pleased with it. Perhaps others are as well. It remains one of the most popular pages on my blog. I play in Linux now. The game works great in Linux. And if you aren't using Linux, my question to you is, why not? It's free. It does not require an anti-virus or much of anything else. It will run fine on a Pentium 4 with a gigabyte of RAM--or less. Again, why not? Download Linux Mint today and see what you think.

As for the new Stone Soup team, well, I like what they've done. Gozag is my "go-to" God for Mummies. The devs have made some rather controversial changes. I do wish that they would do something besides adding a new God every other release. Polytheism is cool, but you know, new content is best, in particular for the higher levels. Let us expand the divine astral realms and allow the player to contend with the gods themselves. Also, there are more Hells to conquer, more demons and devils. What about Lovecraft's mythos? Nyarlhotep, oh my, and Cthulu! These would be interesting challenges to place before the high-level player. Do note that Lovecraft is long since dead, and copyright issues should be null, but of course, I am not a lawyer, and publishers are greedy. In my opinion, there are enough gods as it is, and some gods, such as Sif Muna, cry out to the gods for an overhaul. I can't think of any reason anyone would want to worship Sif Muna when Vehumut offers so much more to the spellcasting faithful.

My Dungeon Crawl Cheat page is laden with dust. Frequent references to Windows XP betray its antiquity. I could edit and add guidance for Windows 10, but why? I like the patina. I will never use Windows XP in this life. I tossed my last Windows XP install DVD. XP is best buried. It was good in its day, but its day is past. There are too many limitations and vulnerabilities. I remember frequent problems with Windows XP and more particularly, Windows 2000, which kept having Registry problems. I read all about the "hive," but still did not understand it. In the end, we must heed Microsoft when they say upgrade. It is their product, after all.

Will Dungeon Crawl survive? Probably not. At some point, the Devs will age to a point when they cannot be bothered anymore. It is the same with Wesnoth and other old games. The younger generation has very high expectations in terms of graphics and whatnot. I hope the Devs continue as long as they possibly can, because I think the game is awesome, but there are many who grow accustomed to modern gaming with high-resolution graphics. I prefer slow, turn-based gaming over realtime, with its emphasis on hand-eye coordination, and I believe there will always be a market for that, so perhaps there is a slender hope for Dungeon Crawl into the future.

How to Cheat in Dungeon Crawl

The only annoying element of the rogue-like game "Dungeon Crawl" is that your character can get killed suddenly and that's that.. You have to start over. From scratch. After I have invested 50,000 turns in a character, I'm not in the mood for the reality of death. There are two ways to cheat death in Crawl: Wiz Mode and the use of a Windows batch file or Linux script to run the game. I prefer the latter. Due to the additional features offered by this batch file, even if one doesn't cheat, it is a convenient way to run Crawl.

The idea behind the batch file is that whenever you reach a point where you would like to preserve your existing character, you can save, exit the game, and the batch file will backup the Save directory to a new directory that the game will not modify. If you later get killed, then the batch file can copy this backup directory over to the Save directory, and you can resume from that point.

Hardcore crawlers refer to this practice as "save scumming," and prudes disapprove, which is weird, considering it's just a game. I find the angry reactions aroused by the idea of so-called "cheating" to be peculiar and amusing. All around the Internet and even in comments on my own blog, one can find Dungeon Crawlers scolding other players about this. It is like some kind of religious injunction. I pay it as much mind as I do other religious injunctions.

Here's my handy-dandy script (batch) file for cheating at Dungeon Crawl. At a minimum, it is compatible with either Linux or Windows, both of which I use.

Although I developed the Windows batch for Windows XP, it now supports Windows 10, which is what I use. I can no longer certify Windows XP or 7 support, since I no longer use XP or 7, and you should not use these outdated systems, either. Time to move on, chilluns. If you do not like Windows 10, that is certainly O.K., move over to the wonderful world of Linux, but do not stay with an antiquated security hole of an operating system. However, I suspect that the few remaining stubborn holdouts still risking their sanity with Windows XP or 7 could get the batch working without too much difficulty. I used to play Crawl on Windows XP, back when I had an XP system. I know for sure that the batch file then ran perfectly on XP back then. But you know, I have made changes since.

I've tried to distill as much intelligence as I can into the batch. I do not use the Installer, but the batch will adjust its pathnames automatically upon successful detection of an Installer-created Dungeon Crawl Stone Soup installation. If you encounter any problems, it will more than likely have to do with the pathnames used by your version of Windows or else unsupported batch commands. There is help widely available on the Internet for programming in batch, but I will attempt to help anyone that has a problem that is likely to be shared among many users. I enjoy programming in batch language, because it does not require a cumbersome and slow compiler, but concede that the language is quite limited both in capability and debugging options. I have my own ways of debugging that work for me although they are quite challenging, but the challenge is part of the fun for me. Even with good technique, often it takes guesswork and plenty of knowledge to deduce what is going on. So if you get into batch programming, first of all don't get into batch programming--but if you do, then prepare to search Google on a regular basis for tips, tricks and syntax, because Microsoft Help is not always quite as helpful as it could be. I have been banned by Google from searching in the past due to the frequency of my requests. Google interpreted my behavior as being similar to that of a bot. But that is how I learned how to program in Linux script and Windows batch.

I have been using some variation of this batch file for years to play Dungeon Crawl. Happy Crawling!

LINUX Installation: With your mouse, click somewhere in the box below. My javascript should highlight the entire contents of the textbox for your convenience. If it does not, then press Ctrl-A to highlight all of the text, then copy (i.e., press Ctrl-C) to your clipboard. Load a plain text editor and paste the clipboard contents (i.e., Ctrl-V) in that window. Inspect the batch, checking for any instances of Blogger's word wrapping breaking up long lines. Save the text file as "regen.sh". I place my script in /home/games/regen_as regen.sh, but you can store it wherever you like. Open a terminal and modify the security of the script using the syntax, "chmod +x regen.sh". Next, set up a launcher to run the included script file from your desktop. When creating the shortcut, click the "Application" tab, click the "Advanced Options" button, and check the box for "Run in terminal." Run the game at least once by itself before using regen.sh, so that the game can create all its data directories. Additional instructions will be found in the script itself. You can get creative for a launcher icon.

#!/bin/bash
###########################################
# I recommend Jedit for coding in Linux
###########################################
#debug option for use if something's amiss:
###########################################
# set -x
###########################################

# Housekeeping
# -----------------------------------------
# Variables which may be modified as needed 
# -----------------------------------------
foreground=7
fg_cyan="$(tput setaf 6)"
#
##where the executable is found
game=/usr/games/crawl-tiles
##where the saves directory may be found
crawldir=$HOME/.crawl
##
#config directory
configdir=/usr/share/crawl/settings
##where init.txt is found
settings=$configdir/init.txt
##where macro file is found
macro=$crawldir/macro.txt
# -----------------------------------------
#This variable is used to test for the existence of a save.
#After a game, if a save does not exist, the character died.
#-----------------------------------------
save_file=$crawldir/saves
#-----------------------------------------
#Specify location of primary and secondary backup directory
#-----------------------------------------
backup1=$crawldir/backup_saves
backup2=$crawldir/backup_saves_2
#
#define 'liberal permissions' for a directory
#some may prefer a more restrictive definition than 777
liberality=777
#keypress that controls regeneration
exitchar="r"
#controls whether user is using two monitors and two desktops and whether
#to adjust display settings accordingly
wmctrl_fix=YES
#users with only one monitor might wish to turn this off


cd "$crawldir"


### Functions

displayscreen () {
tput setb 0
tput setf $foreground
tput clear
tput bold
echo "regen.sh for Dungeon Crawl Stone Soup"
tput sgr0
tput setb 0
tput setf $foreground
echo "Linux version, updated June 15th, 2014"
echo "by igor at http://techlorebyigor.blogspot.com"
echo
echo "File Locations:"
echo "The crawl executable is located at "$game 
echo "Settings are located at "$settings
echo "Save files are located at "$crawldir
echo
echo "Observations:"
}


intro () {
displayscreen
### Preliminary checks
## check for missing programs
##maximize window if wmctrl is available
if [ -z "$(command -v wmctrl)" ]; then
   echo "- wmctrl is not installed, but it is not required."
   wmctrl_fix=NO
else 
#   echo "+ wmctrl is available, allowing regen to maximize its window...let's try!"
#   wmctrl -r :ACTIVE: -b toggle,maximized_vert,maximized_horz
## give the computer time enough to finish executing wmctrl
#   sleep 1
## adjust number of columns available
#   displayscreen
   echo "+ wmctrl is available, allowing regen to maximize its window."
fi

if [ "$wmctrl_fix" == "YES" ] ; then
   echo "+ multi-desktop fix is enabled."
else
   echo "- multi-desktop fix is disabled."
fi

if [ -z "$(command -v grep)" ]; then
   echo "- grep is not installed. Regen uses grep to make observations."
else
   echo "+ grep is available."
fi

savefile=0
if [ -d $backup1 ]; then
   tput setf 5
   savefile=1
   echo "+ Crawl save created by regen.sh found ("$backup1")."
      tput setf $foreground
fi

crawlfound=0
if test -n "$(find "/usr/games" -maxdepth 1 -name 'crawl*' -print -quit)" 
then
   crawlfound=1
fi 

if [ $crawlfound -eq 0 ]; then
  echo "Fatal Error: " $game " not found!"
  echo "It appears that you have not installed Crawl yet."
  echo "Install Crawl and run it once prior to using this script."
  read -n1 -s -p"Press any key to exit."
  exit
fi

#test whether there is any file matching pattern *.cs in the saves dir
checksave
errorflag=0
permission_fault=0
perm=`stat -c '%a' $settings`

if [ "$perm" == "$liberality" ]; 
then
   echo "+ liberal permissions set for " $settings
else 
   echo "- liberal permissions not set for " $settings
   permission_fault=1   
fi
   
perm=`stat -c '%a' $crawldir`
if [ "$perm" == "$liberality" ]; 
then
   echo "+ liberal permissions set for " $crawldir
else 
   echo "- liberal permissions not set for " $crawldir
   permission_fault=1   
fi
   
if [ "$(whoami)" = "root" ]; then 
   echo "+ This script is running with root privileges."
else
   echo "- This script is not running with root privileges."
   if [ $permission_fault -gt 0 ]; then 
      errorflag=1 
      echo
      echo "Linux may complain about permissions unless the permissions to two directories are liberalized via"
      echo "sudo chmod -R "$liberality" "$settings " ; chmod -R "$liberality" " $crawldir
      echo 
      echo "Enter your root password, below, to liberalize permissions now."
      sudo chmod -R $liberality $configdir
      sudo chmod -R $liberality $crawldir 
   fi
fi
errorflag=0
if [ ! -f $game ]; then
   errorflag=1
   echo "Fatal Error: " $game " not found"
fi

if [ ! -d $crawldir ]; then
   echo "***Possible Problem: " $crawldir " not found"
   echo "Crawl may not have created the directory yet, so this is not a fatal error."
fi

if [ ! -f $settings ]; then
   errorflag=$((errorflag+1))
   echo "Fatal Error: " $settings " not found"
fi

if [ $errorflag -gt 0 ]; then 
  echo $errorflag " Fatal Errors found. Suggestion: modify the script, correcting the file paths."
  read -n1 -s -p"Press any key to exit."
  exit
fi

if grep -q "restart_after_game = false" "$settings"
then
##  word found in filename
echo "+ Crawl will return to regen.sh at end of game. "
else
  echo "##" >> "$settings"
  echo "## Modification inserted by regen.sh $(date)"  >> "$settings"
  echo "##" >> "$settings"
  echo "restart_after_game = false" >> "$settings"
  if grep -q "restart_after_game = false" "$settings"
  then
  echo "+ Now Crawl will return to regen.sh at end of game. "
  else
      echo "Warning:"
      echo "regen.sh needs to modify the crawl settings to not restart after game."
      echo "In order to do so, it must be run with root privileges."
  fi
fi
}


checksave() {
savefile=0
#test whether there is any file matching pattern *.cs in the saves dir
if test -n "$(find "$save_file" -maxdepth 1 -name '*.cs' -print -quit)" 
then
   savefile=1
   tput setf 5
   echo "+ Crawl save created by Crawl found ("$save_file")."
   tput setf $foreground
fi 

if test -n "$(find "$save_file/sprint" -maxdepth 1 -name '*.cs' -print -quit)" 
then
   savefile=1
   tput setf 5
   echo "+ Sprint save created by Crawl found ("$save_file"/sprint)."
   tput setf $foreground
fi 

if test -n "$(find "$save_file/zotdef" -maxdepth 1 -name '*.cs' -print -quit)" 
then
   savefile=1
   tput setf 5
   echo "+ Zotdef save created by Crawl found ("$save_file"/zotdef)."
   tput setf $foreground
fi 

if [ $savefile -eq 0 ]; then
   echo "- game save file not found."
fi
return "$savefile"
} 



regen() {
if [ -d $backup1 ]; then
#spare the directories deb and des, because they do not change and are time-consuming for Crawl to create.
   rm -f $save_file/*.*
   rm -rf $save_file/sprint
   rm -rf $save_file/zotdef
   cp -r $backup1/* saves
fi

echo
echo "You are playing the game. . ."
echo
if [ "$wmctrl_fix" == "YES" ] ;
then
#load the game, and after that has been done, sleep 2 seconds, then fix the window to span but one desktop rather than two
#if this is not working, try increasing the sleep period to as long as it takes to load and execute crawl
    $game & sleep 2 && wmctrl -x -r crawl-tiles.crawl-tiles -b toggle,fullscreen
    echo
    echo "(Pause)"
    echo
    read -n1 -s -p"When you have finished playing the game, press any key to continue."
else
#there may be no need for that sort of thing
    $game
fi  
echo
echo ". . .and now you have exited from the game."
echo
}



pause() {
keypoll="a"
while [ "$keypoll" != "$exitchar" ] ; do
echo
#In Linux, it is awkward to use the spacebar for input. So r to continue.
echo "Press q to quit, c to clear screen, ! to delete all saves and backups, m to install mods, or "$fg_cyan$exitchar" to regenerate. . ."
tput setf $foreground
read -n1 -s keypoll
echo $keypoll
if [ "$keypoll" == "q" ] || [ "$keypoll" == "Q" ]; then
   echo "Q was pressed."
   echo "Quitting."
   echo "See ya later!"
   exit 
fi
if [ "$keypoll" == "c" ] || [ "$keypoll" == "C" ]; then
   intro
fi
if [ "$keypoll" == "!" ]; then
#spare the directories deb and des, because they do not change and are time-consuming for Crawl to create.
   if [ -d saves ]; then 
      rm -f $save_file/*.*
      rm -rf $save_file/sprint
      rm -rf $save_file/zotdef
   fi
   if [ -d $backup1 ]; then rm -rf $backup1
   fi
   if [ -d $backup2 ]; then rm -rf $backup2
   fi
   echo "All saves and backups have been deleted."
fi
if [ "$keypoll" == "m" ]; 
then
   if grep -q "inserted by regen.sh" "$macro" 
   then
##  echo "$word found in $filename"
      echo "igor's macros and mods have already been installed:"
      cat "$macro"
   else
      echo "##" >> "$macro"
      echo "## Begin of Modifications inserted by regen.sh $(date)"  >> "$macro"
      echo "##" >> "$macro"
      echo "M:\{-282}" >> "$macro"
      echo "A:Zap" >> "$macro"
      echo "M:\{-289}" >> "$macro"
      echo "A:Vap" >> "$macro"
      echo "##" >> "$macro"
      echo "## End of Modifications inserted by regen.sh $(date)"  >> "$macro"
      echo "##" >> "$macro"

      echo "##" >> "$settings"
      echo "## Begin Modification inserted by regen.sh $(date)"  >> "$settings"
      echo "##" >> "$settings"
      echo "tile_skip_title = true" >> "$settings"
      echo "tile_full_screen = true" >> "$settings"
#this causes conflicts with the screensaver
#      echo "tile_update_rate = 99000" >> "$settings"
      echo "tile_runrest_rate = 1000" >> "$settings"
      echo "##" >> "$settings"
      echo "## End Modification inserted by regen.sh $(date)"  >> "$settings"
      echo "##" >> "$settings"
      echo "igor's macros and mods have now been installed"
   fi
fi
done
echo $exitchar" pressed. Regenerating. . ."
}



### First Run

errorflag=1
intro
pause

### Main Loop

while [ 1 ]; do
regen

tput setf 5
checksave
retval=$?
if [ "$retval" -gt 0 ]; then
##a save file exists
  if [ -d $backup2 ]; then
    rm -rf $backup2
  fi
  mkdir $backup2
  if [ -d $backup1 ]; then
    mv $backup1/* $backup2
    rm -rf $backup1
  fi
  mkdir $backup1
  cp -f $save_file/*.* $backup1
  cp -rf $save_file/zotdef $backup1
  cp -rf $save_file/sprint $backup1
  echo "Your save game has been backed up."
  echo "Press "$exitchar" to resume your game or Q to quit for now."
else
# a save file does NOT exist
  echo
  echo "You were defeated by the reactionaries!"
  if [ -d $backup1 ]; then
    echo "Liberalism has science on its side!"
    echo "We have the technology to bring you back to life!"
    echo "Press "$exitchar" to rise from the dead!"
  else
    echo "No backup available. You're monster food!"
    echo "Burp!"
  fi
fi

tput setf $foreground
pause
intro
done

### End

WINDOWS Installation: With your mouse, click somewhere in the box below. My javascript should highlight the entire contents of the textbox for your convenience. If it does not, then press Ctrl-A to highlight all of the text, then copy (i.e., press Ctrl-C) to your clipboard. Load Notepad++ or a similar plain text editor (Notepad, if you must) and paste the clipboard contents (i.e., Ctrl-V) in that window. Inspect the batch, checking for any instances of Blogger's word wrapping breaking up long lines. Save the text file as "regen.bat". The file must have a .bat extension, because Windows will not execute it if it does not. Create a shortcut to "regen.bat" on your Windows desktop and use that shortcut to play the game.

@echo off
@echo off
rem -----------------------------------------
rem The following line reflects where
rem Crawl is stored on your PC. This is the one
rem line you modify if the batch won't work.
rem Note: regen.bat lives there too, beside crawl.exe
rem -----------------------------------------
rem remember the current directory where regen.bat resides
rem -----------------------------------------
set homedir=\archives\games\crawl
rem -----------------------------------------
if not exist %homedir%\regen.bat set homedir=%cd%
set drv=c:
%drv%
:reboot
cd\
rem -----------------------------------------
set crawldir=%homedir%
rem -----------------------------------------
set crawlexe=crawl.exe
set savedir=%crawldir%\saves
rem -----------------------------------------
rem This variable is used to test for the existence of a save.
rem -----------------------------------------
set save_file=*.cs
rem -----------------------------------------
rem Specify location of primary backup directory
rem Important: this directory is deleted.
rem If modifications are made, take care to specify 
rem correct pathnames, as the savedir, backup1,
rem and backup2 directories are subject to irretrievable
rem deletion during the normal course of this batch.
rem -----------------------------------------
set backup1=%crawldir%\backup_saves
set backup2=%crawldir%\backup_saves_2
rem -----------------------------------------
rem Check the pathname assumptions and make
rem a few adjustments if necessary due to use of Installer or 
rem different version of Windows
rem -----------------------------------------
if exist "%crawldir%\%crawlexe%" goto skipverify
set crawlexe=crawl.exe
if exist "%crawldir%\%crawlexe%" goto skipverify
rem -----------------------------------------
rem Check whether the Installer was used for all users.
rem (The Installer can install for all users or only for one.)
rem Note: The ProgramFiles variable is set by the OS.
rem -----------------------------------------
set crawldir=%ProgramFiles%\Crawl
if exist "%crawldir%\%crawlexe%" goto installer
rem -----------------------------------------
rem Installer may have selected just one user.
rem Note: The USERPROFILE variable is set by the OS.
rem -----------------------------------------
set crawldir=%USERPROFILE%\Local Settings\Application Data\Crawl
if exist "%crawldir%\%crawlexe%" goto installer
rem -----------------------------------------
rem Attempt to conform to Windows 7 based on suggestions by 'Anonymous'
rem -----------------------------------------
set crawldir=%ProgramFiles(x86)%\crawl
rem -----------------------------------------
:installer
rem -----------------------------------------
rem Assume that the Installer was used.
rem Note: The APPDATA variable is set by the OS.
rem -----------------------------------------
set installersave=%APPDATA%\Crawl
rem -----------------------------------------
rem Attempt to conform to Windows 7 based on suggestions by 'Anonymous'
rem -----------------------------------------
if not exist %installersave% set installersave=%APPDATA%\roaming\crawl
rem -----------------------------------------
set backup1=%installersave%\backup_saves
set backup2=%installersave%\backup_saves_2
set savedir=%installersave%\saves

:skipverify
cd "%crawldir%"
set backedup=FALSE

if exist "%crawlexe%" goto checkinit

echo.
echo. Error: unknown filename. Expecting %crawlexe%.
echo. Suggestion: modify the batch as needed.
echo.
pause
:edit_regen
set ae=%homedir%\regen.bat
if not exist %ae% exit
call :editor
Echo.
Echo. Since you may have edited the batch file,
Echo. it is prudent to exit and restart.
pause
exit

:checkinit
rem --------------------------------------------------------
rem Mod init.txt if necessary to prevent Crawl cycling 
rem back to race selection menu upon character death
rem --------------------------------------------------------
rem lightning-fast skip of laborious FIND
rem --------------------------------------------------------
if exist settings\regenned.txt goto decision_time
rem --------------------------------------------------------
rem file does not exist, so do things the hard way
rem --------------------------------------------------------
call :datetime
find /C "restart_after_game = false" settings\init.txt
if errorlevel 1 echo ### mod [come back to me] inserted by regen.bat on %concat_date% at %concat_time% >> settings\init.txt
if errorlevel 1 echo restart_after_game = false >> settings\init.txt
echo ### init.txt has already been patched by regen.bat. No need to patch it again! > settings\regenned.txt
:decision_time
color 0B
cls
cd "%crawldir%"
echo Regen.bat for Dungeon Crawl Stone Soup, updated May 19th, 2019
echo by igor at http://techlorebyigor.blogspot.com
echo.
set bmsg=
set ba=backup available.
if exist "%backup1%\%save_file%" set bmsg=%bmsg% Crawl %ba%
if exist "%backup1%\sprint\%save_file%" set bmsg=%bmsg% Sprint %ba% 
if exist "%backup1%\zotdef\%save_file%" set bmsg=%bmsg% Zot Defense %ba%
if /I "%message%" NEQ "" echo %message%
if /I "%bmsg%" NEQ "" echo Liberalism has science on its side!
if /I "%bmsg%" NEQ "" echo We have the technology to bring you back to life!
echo.
if /I "%bmsg%" NEQ "" echo %bmsg%
echo.
set choose_label=[r]estart, [m]ods, or [q]uit
echo. To restart Crawl, press 'r'
if /I "%bmsg%" NEQ "" echo. To delete temporary saves and start afresh, press '!'
if /I "%bmsg%" NEQ "" set choose_label=[d]delete, %choose_label%
echo. To access the magical mods menu, press 'm'
echo. If you're satisfied with a heroic death, press 'q' to quit.
echo.
set userinput=0
:simplequery
choice /c:rdmq > nul
rem the above line replaces the one commented out, below:
rem  set /P userinput=Input your command and press Enter.
if errorlevel 1 set userinput=r
if errorlevel 2 set userinput=d
if errorlevel 3 set userinput=m
if errorlevel 4 set userinput=q

if "%userinput%"=="" goto decision_time
if /I %userinput%==r goto begin
if %userinput%==d goto deletegames
if /I %userinput%==m goto mods
if /I %userinput%==q exit
goto decision_time

:begin
color 0D
rem --------------------------------------------------------
rem If player recently backed up saved game, no need to copy
rem --------------------------------------------------------
if %backedup%==TRUE goto housekeeping
rem --------------------------------------------------------
rem Prepare to restore the preserved save files from backup_saves.
rem --------------------------------------------------------
if exist "%backup1%" del "%savedir%\*.*" /Q
if exist "%backup1%\sprint" del "%savedir%\sprint" /Q
if exist "%backup1%\zotdef" del "%savedir%\zotdef" /Q
rem --------------------------------------------------------
rem Restore backup directory to the saves directory.
rem It is necessary to copy the sprint subdirectory.
rem --------------------------------------------------------
if exist "%backup1%" copy "%backup1%\*.*" "%savedir%" /Y
if exist "%backup1%\sprint" copy "%backup1%\sprint" "%savedir%\sprint" /Y
if exist "%backup1%\zotdef" copy "%backup1%\zotdef" "%savedir%\zotdef" /Y
:housekeeping
set backedup=FALSE
if exist "%savedir%\logfile". del "%savedir%\logfile".
if exist "%savedir%\logfile-sprint". del "%savedir%\logfile-sprint".
if exist "%savedir%\logfile-zotdef". del "%savedir%\logfile-zotdef".
if exist "%savedir%\scores-zotdef". del "%savedir%\scores-zotdef".
if exist "%crawldir%\arena.result". del "%crawldir%\arena.result".
color 02
echo.You are currently playing the game...
%crawlexe%
rem --------------------------------------------------------
rem Set default messages
rem --------------------------------------------------------
set message=You have quit the game...
echo. %message%
rem --------------------------------------------------------
rem Existing arena.result indicates Arena was played
rem --------------------------------------------------------
if not exist "%crawldir%\arena.result" goto other_tests
cls
type "%crawldir%\arena.result"
echo.
pause
goto housekeeping

:other_tests
rem --------------------------------------------------------
rem Test for an exit from generic Crawl.
rem --------------------------------------------------------
set logfile=%savedir%\logfile
rem --------------------------------------------------------
rem Missing logfile indicates the current character survived
rem --------------------------------------------------------
if exist "%logfile%" goto testlogfile
rem --------------------------------------------------------
rem Test for an exit from Sprint. 
rem --------------------------------------------------------
set logfile=%savedir%\logfile-sprint
if exist "%logfile%" goto testlogfile
rem --------------------------------------------------------
rem Test for an exit from Zot Defense. 
rem --------------------------------------------------------
set logfile=%savedir%\logfile-zotdef
if exist "%logfile%" goto testlogfile
rem --------------------------------------------------------
rem Log file does not exist. 
rem At any rate, character survived.
rem --------------------------------------------------------
goto normalsave

:testlogfile
rem --------------------------------------------------------
rem If there was a killer, then the current character is dead.
rem This is the most likely scenario.
rem --------------------------------------------------------
find /C "killer=" "%logfile%"
rem --------------------------------------------------------
rem An errorlevel of 1 indicates the search text was not found
rem --------------------------------------------------------
if errorlevel 1 goto quittest
set message=You were defeated by the reactionaries!
goto decision_time
:quittest
rem --------------------------------------------------------
rem Check whether player quit game
rem --------------------------------------------------------
find /C "ktyp=quit" "%logfile%"
if errorlevel 1 goto checkforwin
set message=You quit the game. 
goto decision_time
:checkforwin
rem --------------------------------------------------------
rem If character won, quit.
rem --------------------------------------------------------
find /C "ktyp=win" "%logfile%"
if errorlevel 1 goto test_for_death
cls
echo.
echo. Congratulations on your victory!
echo.
pause
exit
:test_for_death
rem --------------------------------------------------------
rem Ktyp with unknown text indicates character was slain
rem --------------------------------------------------------
find /C "ktyp=" "%logfile%"
if errorlevel 1 goto decision_time
set message=You were defeated by the reactionaries!
goto decision_time

:editor
cls
echo. Environmental variables:
echo.
echo. Drive name is %drv%. Game directory is %crawldir%. Crawl .exe is %crawlexe%
echo. Saves directory is %savedir%
echo. Saves are backed up to %backup1% 
echo. and %backup2%
echo. Save file indicator is %save_file%
echo.
echo.
echo Loading text editor...
rem --------------------------------------------------------
rem Vastly improved functionality is possible with Notepad++
rem --------------------------------------------------------
set notepad=\Program Files\Notepad++\notepad++.exe
if exist "%notepad%" call "%notepad%" "%ae%"
if not exist "%notepad%" call notepad "%ae%"
GOTO :EOF

:edit_init
set ae=%crawldir%\settings\init.txt
call :editor
goto mods

:datetime
rem deduce date
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set year=%%c
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set month=%%a
for /f "tokens=2-4 delims=/ " %%a in ('date /T') do set day=%%b
set concat_date=%year%-%month%-%day%

rem deduce time
for /f "tokens=1 delims=: " %%h in ('time /T') do set hour=%%h
for /f "tokens=2 delims=: " %%m in ('time /T') do set minutes=%%m
for /f "tokens=3 delims=: " %%a in ('time /T') do set ampm=%%a
set concat_time=%hour%%minutes%%ampm%
GOTO :EOF

:deletegames
rem --------------------------------------------------------
rem Delete all saved games and start afresh
rem --------------------------------------------------------
if exist "%backup1%" rd "%backup1%" /S /Q
if exist "%backup2%" rd "%backup2%" /S /Q
rem --------------------------------------------------------
rem Spare the subdirectories db and des.
rem --------------------------------------------------------
del "%savedir%\*.*" /Q
if exist "%savedir%\sprint" rd "%savedir%\sprint" /S /Q
if exist "%savedir%\zotdef" rd "%savedir%\zotdef" /S /Q
goto housekeeping

:preserve
if not exist "%backup1%" goto mods_menu
rem --------------------------------------------------------
rem Preserve the main saved game directory (backup1) in a
rem unique directory that will never be deleted by regen.bat
rem --------------------------------------------------------
call :datetime
rem concat unique dir name
set preserve=preserve\%concat_date%\%concat_time%
cd "%crawldir%"
if not exist preserve md preserve
cd preserve
if not exist %concat_date% md %concat_date%
cd %concat_date%
if not exist %concat_time% md %concat_time%
cd %concat_time%

copy "%backup1%\*.*" /Y
set s=%backup1%\sprint\%save_file%
set z=%backup1%\zotdef\%save_file%
if exist "%s%" md sprint
if exist "%s%" copy "%backup1%\sprint" sprint /Y
if exist "%z%" md zotdef
if exist "%z%" copy "%backup1%\zotdef" zotdef /Y
echo.
echo. Saved game has been stored in a unique directory:
echo. %crawldir%\%preserve%.
echo. Manually copy the files to backup1 whenever desired.
echo.
pause
goto mods_menu

:mods
color 02
cd "%crawldir%\settings"
set speed=ACTIVE
set commanden=ACTIVE
set macro=ACTIVE
set perm=ACTIVE
set fullscreen=ACTIVE
set fi=init.txt
rem --------------------------------------------------------
rem Test init.txt for version .11 
rem --------------------------------------------------------
color 03
if not exist macro.txt set macro=INACTIVE
if %macro%==INACTIVE goto skipmacro
color 05
find /C "A:Zap" macro.txt >nul
if errorlevel 1 set macro=INACTIVE
:skipmacro
color 04
find /C "remember_name = true" %fi% >nul
if errorlevel 1 set perm=INACTIVE
color 02
find /C "tile_update_rate = 5500" %fi% >nul
if errorlevel 1 set speed=INACTIVE
color 01
find /C "commanden" %fi% >nul
if errorlevel 1 set commanden=INACTIVE
color 08
find /C "tile_full_screen = true" %fi% >nul
if errorlevel 1 set fullscreen=INACTIVE
:mods_menu
cls
echo. Igor's Magical Mods Menu
echo. ------------------------
echo.
echo. Speed mod: %speed%
echo. Macro mod: %macro%
echo. Tiles Full screen mod: %fullscreen%
echo. Command Enhancement mod: %commanden%
echo.
color 02
set choose_label=[z]ip, [i]nit, [b]atch, [g]o back, or [q]uit
if %speed%==INACTIVE echo. To select speed enhancement, press 'e'
if %speed%==INACTIVE set choose_label=[s]peed, %choose_label%
if %fullscreen%==INACTIVE echo. To select tiles full screen, press 'f'
if %fullscreen%==INACTIVE set choose_label=[f]ull, %choose_label%
if %macro%==INACTIVE echo. To select igor's macros, press 'm'
if %macro%==INACTIVE set choose_label=[m]acro, %choose_label%
if %commanden%==INACTIVE echo. To select command enhancements, press 'c'
if %commanden%==INACTIVE set choose_label=[c]md, %choose_label%
if exist "%backup1%" echo. To preserve your saved game long-term in a unique directory, press 'p'
if exist "%backup1%" set choose_label=[p]reserve, %choose_label%
echo. To install a new Zip of Tiles-Crawl, press 'z'
echo. To edit init.txt, press 'i'
echo. To edit the batch file and quit, press 'b'
echo. To go to the main menu, press 'g'
echo. To quit, press 'q'
echo.
set userinput=0
color 0A
:simplequery2
set action=
choice /c:qgpbzecifm > nul
rem the above line replaces the one commented out, below:
rem  set /P userinput=Input your command and press Enter.
if errorlevel 1 set userinput=q
if errorlevel 2 set userinput=g
if errorlevel 3 set userinput=p
if errorlevel 4 set userinput=b
if errorlevel 5 set userinput=z
if errorlevel 6 set userinput=e
if errorlevel 7 set userinput=c
if errorlevel 8 set userinput=i
if errorlevel 9 set userinput=f
if errorlevel 10 set userinput=m
if "%userinput%"=="" goto mods_menu
if /I %userinput%==q exit
if /I %userinput%==g goto decision_time
if /I %userinput%==p goto preserve
if /I %userinput%==b goto edit_regen
if /I %userinput%==z goto install
if /I %userinput%==e set action=speed
if /I %userinput%==c set action=commandenhance
if /I %userinput%==i goto edit_init
if /I %userinput%==f set action=fullscreen
if /I %userinput%==m set action=macro
call :datetime
set fi=init.txt
if %action%==speed goto chkspeed
if %action%==fullscreen goto chkfull
if %action%==commandenhance goto chkcomm
if %action%==macro goto macro
echo. ERROR: Unexpected response
pause
exit

:chkspeed
if %speed%==ACTIVE goto mods_menu
call :backup_fi
echo tile_update_rate = 5500 >> %fi%
echo tile_runrest_rate = 500 >> %fi%
echo tile_skip_title = true  >> %fi%
goto mods

:chkfull
if %fullscreen%==ACTIVE goto mods_menu
call :backup_fi
echo tile_full_screen = true >> %fi%
goto mods

:chkcomm
if %commanden%==ACTIVE goto mods_menu
call :backup_fi
echo auto_list = true       >> %fi%
echo auto_switch = true     >> %fi%
echo equip_unequip = true   >> %fi%
echo allow_self_target=no   >> %fi%
echo auto_drop_chunks =yes  >> %fi%
echo easy_exit_menu = false >> %fi%
goto mods

:macro
if %macro%==ACTIVE goto mods_menu
set fi=macro.txt
rem --------------------------------------------------------
rem macro.txt does not necessarily exist in a fresh install
rem --------------------------------------------------------
if not exist %fi% echo. > %fi%
call :backup_fi
rem --------------------------------------------------------
rem The Function keys (F1 - F12) appear to be coded thus:
rem F1 is \{-282}
rem F2 is \{-283} ...and so on?
rem 
rem A helpful macro for spellcasters
rem press F1 for Z a p
rem a helpful macro for artificers & others would be
rem press F8 for V a p
rem --------------------------------------------------------
echo M:\{-282} >> %fi%
echo A:Zap >> %fi%
echo M:\{-289} >> %fi%
echo A:Vap >> %fi%
goto mods

:backup_fi
if not exist %fi%.bak copy %fi% %fi%.bak /Y
echo # >> %fi%
echo ### mod [%action%] inserted by regen.bat on %concat_date% at %concat_time% >> %fi%
goto :EOF

:normalsave
if exist "%savedir%\%save_file%" goto save_game
if exist "%savedir%\sprint\%save_file%" goto save_game
if exist "%savedir%\zotdef\%save_file%" goto save_game
rem --------------------------------------------------------
rem if no save file, do not bother backing up
rem --------------------------------------------------------
goto decision_time

:save_game
cls
rem Pause may not be necessary. Let us try going without it for a spell.
rem echo. If you wish to backup your game, press any key to continue.
rem echo. Otherwise, press Ctrl-C to quit.
rem pause

if exist "%backup2%" rd /S /Q "%backup2%"
md "%backup2%"
copy "%backup1%\*.*" "%backup2%" /Y
set s=%backup1%\sprint\%save_file%
set z=%backup1%\zotdef\%save_file%
if exist "%s%" md "%backup2%\sprint"
if exist "%s%" copy "%backup1%\sprint" "%backup2%\sprint" /Y
if exist "%z%" md "%backup2%\zotdef"
if exist "%z%" copy "%backup1%\zotdef" "%backup2%\zotdef" /Y

if exist "%backup1%" rd /S /Q "%backup1%"
md "%backup1%"
copy "%savedir%\*.*" "%backup1%" /Y
set s=%savedir%\sprint\%save_file%
set z=%savedir%\zotdef\%save_file%
if exist "%s%" md "%backup1%\sprint"
if exist "%s%" copy "%savedir%\sprint\*.*" "%backup1%\sprint" /Y
if exist "%z%" md "%backup1%\zotdef"
if exist "%z%" copy "%savedir%\zotdef\*.*" "%backup1%\zotdef" /Y

set message=You have backed up your saved game.
set backedup=TRUE

goto decision_time

:install
color 0F
cls
echo Install-New-Crawl for Dungeon Crawl
echo by igor at http://techlorebyigor.blogspot.com
echo.
rem ---------------------------------------
set dldir=\pelf
set unzipper="%ProgramFiles%\WinRAR\winrar.exe"
set unzipcommand="x"
set gamedir=\games
set cdir=crawl
set ErrorOut=NO
rem ---------------------------------------
echo You are about to install a new version of crawl.
echo.You must have either WinRar or 7-Zip installed for this to work.
echo.You must have a .zip of Crawl already in the download directory.
echo.
if not exist %unzipper% set unzipcommand="x"
if not exist %unzipper% set unzipper="%ProgramFiles%\7-Zip\7z.exe"
if not exist %unzipper% set ErrorOut=YES
rem maybe user downloads to same dir that regen.bat lives in.
if not exist %dldir% set %dldir%=%homedir%
set dlfile=crawl_
rem the boys keep changing the zip name
if not exist "%dldir%\%dlfile%*" set dlfile=stone_soup
if not exist "%dldir%\%dlfile%*" set ErrorOut=YES
echo.Review the following variables:
echo.Your drive = %drv%
echo.Your download directory where the Crawl zip can be found = %dldir%
echo.Crawl zip name = %dlfile%
echo.Your unzipper = %unzipper%
echo.Crawl will be installed to %gamedir%\%cdir%
echo.%gamedir%\%cdir% will be created if it does not already exist.
echo.
if not exist %unzipper% echo. ERROR: WinRar or 7-Zip is a required program to unpack the archive.
if not exist "%dldir%\%dlfile%*" echo. ERROR: Cannot find the crawl archive (expected in %dldir%)
if %ErrorOut%==YES echo Aborting the install.
if %ErrorOut%==YES pause
if %ErrorOut%==YES goto mods_menu

echo.WARNING: The old version will be deleted, including any saved games! 
echo.Press Ctrl-C or exit this window to ABORT.
echo.Press Enter to CONTINUE with the INSTALL.
pause

if not exist %gamedir% md %gamedir%
cd %gamedir%
rem eliminate the old crawl directory, including any saves
if exist %cdir% rd %cdir% /S /Q
rem prepare temp directory
if exist temp rd temp /S /Q
md temp
cd temp
rem dev team stashes crawl within a directory with similar name as zip,
rem so let's fix that now
move "%dldir%\%dlfile%*.*" igor.zip

%unzipper% %unzipcommand% "%gamedir%\temp\igor.zip"
rem enter the directory created by the archive
cd %dlfile%*
rem discover what the directory is named
set devdir=%cd%
rem now we are on easy street
cd ..
ren %devdir% %cdir%
move %cdir% %gamedir%
rem cleanup
cd ..
rd temp /S /Q
goto reboot 

General Notes:

• This batch file, and any page on Igor's blog, is not static but is subject to change--improvement--at any time. You may link to this page on other web sites and be assured of referencing the very latest version of regen.bat for Windows and regen.sh for Linux at all times now and in the future.
• To use this strategy effectively, you should save your game and quit at a point where you may wish to recover your character later upon any unexpected demise.
• I play the latest version of Crawl, either the trunk (beta) or the last stable release. You have a better chance of the script/batch file working correctly if this is also your scenario. Through the years, the Stone Soup developers have altered the path and file names of the saves directory. However, the script/batch is designed in such a way that modifications are elementary, consisting of one or two edits of constants at the most.
• On my Linux computer, I have created a new directory in Home called games and placed the linux shell script (regen.sh) and its icon in there. I believe it is important for the name of the directory to have no spaces. One must either chmod the two relevant crawl directories in order to permit file copies and deletions or else grant root permissions for this script, because otherwise Linux denies permission to the many file copies. I'm not well-versed on this sort of thing. I used to give my launcher root permissions via "sudo ~/regen.sh", but my current method is to chmod the two crawl directories, because that eliminates the need to enter the root password every time one plays.
• On a Windows computer, regen.bat attempts to self-adjust its assumptions regarding paths--it has some primitive intelligence, not much--but if that doesn't work, regen.bat will tell you so, and at that point you will have to edit the variables relating to pathnames. By design, few pathnames are hardcoded, meaning the batch should be relatively easy to modify.
• Linux has a built-in capability of accepting a single keypress for input and overall a far more robust scripting language than Windows. Batch programming in Windows, however, remains in the Stone Age. It is a wonder I ever programmed the Windows batch at all. For Windows users, as of 05/19/2019, I have finally found the syntax to accept single keypress and no longer use a third-party utility to achieve the same effect. Thus, this cheat is transparent with plain text source code, and no one should feel as though there is anything deceptive about it, although there is no doubt as to its being elaborate. Perhaps more than five minutes would be required to understand how the batch works, but not more than thirty minutes, for an experienced batch programmer.

Release Notes:

• 05/19/2019 Update:
  Change to regen.bat only: modification to work with my Windows 10 system and allow single-keypress responses, i.e. not having to press the Enter key. Users are expected to modify one line in the batch specifying where the game is installed.
• 06/15/2014 Update:
  Change to regen.sh: fix for multi-desktop users like myself. No longer will crawl span both desktops.
• 11/28/2013 Update:
  Change to regen.sh: sleep a second after wmctrl, because the computer takes a random number of milliseconds to adjust the display. Clarify a display message.
• 11/27/2013 Update:
  Change to regen.sh: fix a few bugs. Maximize window if wmctrl is available.
• 10/18/2013 Update:
  Change to regen.sh: corrections to the menu display and new optional mods to automate setting tiles to full screen and other preferences of mine. The script now reflects a change in version 13 of the location of the macro file.
• 9/16/2013 Update:
  Change to regen.sh: Recognize the existence of Sprint and Zotdef saves and tidy up the code a little bit.
• 1/31/2013 Update:
  Change to regen.sh: Handle the case where Crawl has not yet been installed or executed.
• 1/29/2013 Update:
  Just a few minor refinements to text messages in regen.sh and the addition of a loop to handle permission-granting, in case the user types an incorrect password.
• 1/21/2013 Update:
  Once again, Linux refinements only. regen.sh was not handling chmod quite right; chmod -R is more to the point as it liberalizes permissions for all the files and folders within the two relevant Crawl directories. I made a few other changes of no special importance. It is my intention that regen.sh should handle DCSS upgrades seamlessly, asking for permission to chmod when necessary.
• 1/19/2013 Update:
  Further refinements to the Linux script, which is now coming into its own, looking better and acting smarter. Rather than have sudo ask me for my password everytime I play (ach!), I prefer to chmod 777 the permissions of two crawl directories, which is Linuxese for "allowing read/write access to everyone".
• 1/16/2013 Update:
  Added a few minor refinements to the Linux script that occurred to me this evening, including a suggestion for avoiding the annoyance of sudo.
• 1/16/2013 Update:
  Many improvements made and features added to the Linux script. It is somewhat more intelligent now and will attempt to detect and report certain problems before they occur.
• 1/14/2013 Update:
  I have successfully ported regen.bat to Linux! Many improvements made between Jan. 13 & Jan.14th to the Linux script, which does however require root permission in order to shift files around. Through trial and error, I have found that sudo is the thing, not kdesudo, which is for graphical programs. Kdesudo will cause errors. There is no way I know of getting around the permission requirement other than disabling the security altogether on one's system. I'm not quite confident enough to second-guess the Linux developers on that score. I'd rather just play along according to their rules.
• 11/13/2012 Update:
  Minor edits for compatibility with Crawl 12 beta.
• 10/17/2012 Update:
  Colorized the text, added for the first time a free public domain icon, reorganized the main menu, and fixed several bugs throughout the mods menu.
  
  Fixed a little bug that had broken the 'edit batch file' option. Oopsy-daisy. Added a little colorizing trick that had occurred to me.
  
  Improved the efficiency of the Install-New-Crawl option. Fixed the broken macro mod. Added polychromatic effect to mod menu.
  
  Fixed a little issue with install-new-crawl. So many variables now, and of course batch language won't help me in keeping track of them.
• 10/08/2012 Update:
  Add option to install new version of Crawl using 7-Zip or WinRar. This will install the game into a directory that is the default for regen.bat and thus ensure 100% compatibility. Several bug fixes to the Mods menu. Added 'command enhancement' mod.
• 09/30/2012 Update:
  Just a few minor tweaks to improve efficiency. Improved start-up performance by skipping an unnecessary FIND. Eliminated a few redundancies through the use of subroutines. Reworded some comment statements. Everything working well on Windows XP with the latest beta version .11.